# Contibutor: Morten Linderud <foxboron@archlinux.org>
# Contibutor: Alexandre Pujol <alexandre@pujol.io>

pkgname='pass-otp-git'
_pkgname=pass-otp
pkgver=r135.a364d2a
pkgrel=2
pkgdesc='A pass extension for managing one-time-password (OTP) tokens.'
arch=('any')
url='https://github.com/tadfisher/pass-otp'
license=('GPL3')
depends=('pass'
        'oath-toolkit'
        'qrencode')
makedepends=('git')
optdepends=('perl-pass-otp')
provides=('pass-otp')
conflicts=('pass-otp')
# patch from https://github.com/tadfisher/pass-otp/pull/172
source=("git+$url.git"
        '0001-Fix-HOTP-counter-increases.patch')
b2sums=('SKIP'
        'fb97f0b8049bc8349f0dba20ce7b491b280a140aa1ad4f751aba7fb69a8b95986dda83c5ed698540d56ae47c829200bafd653cc4773bb502d095d2baf3861895')

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_pkgname"
  patch -p1 -i "$srcdir/0001-Fix-HOTP-counter-increases.patch"
}

package() {
  cd "$srcdir/$_pkgname"
  make PREFIX=/usr DESTDIR="${pkgdir}" install
}