# Maintainer: Francesco Minnocci <ascoli dot minnocci at gmail dot com>

pkgname=sdcv-git
_pkgname=sdcv
pkgver=0.5.5.r1.gbeebb0f
pkgrel=2
pkgdesc="StarDict Console Version - Git version"
arch=('x86_64' 'aarch64')
url="https://github.com/Dushistov/sdcv"
license=('GPL')
depends=('glib2' 'readline' 'zlib')
makedepends=('cmake' 'git')
# patch from https://github.com/Dushistov/sdcv/pull/104
source=("git+${url}.git"
        '0001-stardict_lib.cpp-use-explicit-const_cast.patch')
b2sums=('SKIP'
       '1f35e85d3240150e79ba234797a4535ed5a93f42f0ea93aaeecfe1d416b02b6b30f84c3686675f2f00422aa47db692ff47e9b323dd8d434e2b93d3aed414ec56')
provides=('sdcv' 'stardict')
conflicts=('sdcv')

pkgver() {
  cd "${srcdir}/${_pkgname}"

  # Get the version number.
  git describe --long | sed 's/^v//;s/-/.r/;s/-/./'
}

prepare() {
  cd "${srcdir}/${_pkgname}"

  patch -p1 -i "$srcdir/0001-stardict_lib.cpp-use-explicit-const_cast.patch"
}

build() {
  cd "${srcdir}/${_pkgname}"

  install -d build
  cd build

  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr ..
  make
  make lang
}

package() {
  cd "${srcdir}/${_pkgname}/build"

  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: