# Maintainer: Francesco Minnocci <ascoli dot minnocci at gmail dot com>

pkgname=sdcv-git
_pkgname=sdcv
pkgver=0.5.5.r1.gbeebb0f
pkgrel=1
pkgdesc="StarDict Console Version - Git version"
arch=('x86_64' 'aarch64')
url="https://github.com/Dushistov/sdcv"
license=('GPL')
depends=('glib2' 'readline' 'zlib')
makedepends=('cmake' 'git')
# patch from https://github.com/Dushistov/sdcv/pull/104
source=("git+${url}.git"
        '0001-stardict_lib.cpp-use-explicit-const_cast.patch')
b2sums=('SKIP'
       'd962abc55b93e487614df556124b1c7f72310332375bb903cd80c8dc5b6afed62ae8f1e11e3751d602bd9ceea5566a1af36a7f8aa70e606150e3d72c7f0423c9')
provides=('sdcv' 'stardict')
conflicts=('sdcv')

pkgver() {
  cd "${srcdir}/${_pkgname}"

  # Get the version number.
  git describe --long | sed 's/^v//;s/-/.r/;s/-/./'
}

prepare() {
  cd "${srcdir}/${_pkgname}"

  patch -p1 -i "$srcdir/0001-stardict_lib.cpp-use-explicit-const_cast.patch"
}

build() {
  cd "${srcdir}/${_pkgname}"

  install -d build
  cd build

  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr ..
  make
  make lang
}

package() {
  cd "${srcdir}/${_pkgname}/build"

  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: